home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 4 NO 1.st / POGOSRC.ARC / STBLASTH.ASM < prev    next >
Encoding:
Assembly Source File  |  1985-11-20  |  13.9 KB  |  860 lines
  1.  
  2.  
  3. ; :ts=8
  4.     dseg
  5.     public _cscreen
  6.     public _lmasks
  7.     public _rmasks
  8.  
  9. _lmasks: dc.w    $ffff,$7fff,$3fff,$1fff
  10.     dc.w     $fff,$7ff,$3ff,$1ff
  11.     dc.w    $ff,$7f,$3f,$1f
  12.     dc.w    $f,$7,$3,$1
  13.  
  14. _rmasks: dc.w    $8000,$c000,$e000,$f000
  15.     dc.w    $f800,$fc00,$fe00,$ff00
  16.     dc.w    $ff80,$ffc0,$ffe0,$fff0
  17.     dc.w    $fff8,$fffc,$fffe,$ffff
  18.  
  19.     cseg
  20.  
  21.  
  22.     public init_hli
  23.     ; init_hli = set up registers with color info so can call hli
  24.     ;     below with less set up than _hline.  Also sets up mask pointers
  25.     ; d0 = color
  26.  
  27. init_hli
  28.         ;a4 points to the hline associated with this color
  29.     move.l    #hline_table,a4    
  30.     asl.w    #2,d0            ;pointer addressing ... *4
  31.     move.l    0(a4,d0.w),a4        ; a4-> color based hline routine
  32.         ;a2 and a3 go to the mask tables
  33.     move.l    #_lmasks,a2
  34.     move.l    #_rmasks,a3
  35.     move.l    _cscreen,a1
  36.     rts
  37.  
  38.  
  39.     public hli
  40.     ; hli(y, x1, x2)
  41.     ; hli - draw a horizontal line while trashing registers:
  42.     ;    d0,d1,d2,d3    a0,a2,a3,a4
  43. hli
  44. first_param  set 4
  45. y  set first_param
  46. x1 set first_param+2
  47. x2 set first_param+4
  48.  
  49.     ; get y address of hline in a0
  50.     move.l    a1,a0
  51.     move.w    y(sp),d0
  52.     lsl.w    #5,d0
  53.     move.w    d0,d1
  54.     add.w    d0,d0
  55.     add.w    d0,d0
  56.     add.w    d1,d0
  57.     adda.w    d0,a0
  58.  
  59.  
  60.     ; add in x component of address to get left end in a0
  61.     move.w    x1(sp),d2 ;peel off copy of x1 for future use
  62.     move.w    d2,d0
  63.     asr.w    #1,d0    ; x2 pixels/bytes
  64.     and.w    #$fff8,d0    ; mask to word boundary
  65.     adda.w    d0,a0
  66.  
  67.     move.w    x2(sp),d3 ; peel off copy of x2 for future use
  68.  
  69.         ;d0 = count = (x2>>4) - (x1>>4) - 1
  70.     move.w    d3,d0
  71.     asr.w    #4,d0
  72.     move.w    d2,d1
  73.     asr.w    #4,d1
  74.     sub.w    d1,d0
  75.  
  76.  
  77.         ;mask out where in word endpoints are
  78.     and.w    #$f,d2
  79.     and.w    #$f,d3
  80.  
  81.  
  82.         ;word addressing of mask tables
  83.     asl    #1,d2
  84.     asl    #1,d3
  85.  
  86.     sub.w    #1,d0
  87.     jmp    (a4)
  88.  
  89.  
  90.  
  91.     public _blast_block
  92.     ;    blast_block(x1, y1, x2, y2, color)
  93.     ;    draws a filled block from upper left corner x1 y1
  94.     ;    to lower right corner x2 y2.
  95. first_param  set 11*4
  96. x1  set first_param
  97. y1  set first_param+2
  98. x2     set first_param+4
  99. y2     set first_param+6
  100. color     set first_param+8
  101. _blast_block
  102.     movem.l    a2/a3/a4/a5/a6/d3/d4/d5/d6/d7,-(sp)
  103.  
  104.  
  105.         ;a4 points to the hline associated with this color
  106.     move.l    #hline_table,a4    
  107.     move.w    color(sp),d0
  108.     and.w    #15,d0        ;mask color to an ok value
  109.     asl.w    #2,d0            ;pointer addressing ... *4
  110.     move.l    0(a4,d0),a4        ; a4-> color based hline routine
  111.  
  112.  
  113.         ;d7 = lines = y2-y1+1
  114.     move.w    y1(sp),d6
  115.     move.w    y2(sp),d7
  116.     sub.w    d6,d7
  117.     add.w    #1,d7
  118.  
  119.         ;set a1 = screen address of first hline
  120.     move.l    _cscreen,a1
  121.     move.w    d6,d0
  122.     mulu    #160,d0
  123.     adda.l    d0,a1
  124.  
  125.  
  126.         ;a2 and a3 go to the mask tables
  127.     move.l    #_lmasks,a2
  128.     move.l    #_rmasks,a3
  129.  
  130.         ;get line endpoints
  131.     move.w    x1(sp),d6
  132.     move.w    x2(sp),d3
  133.  
  134.         ;a1 = line_addr + ((x1>>1)&$fff8)
  135.     move.w    d6,d0
  136.     asr.w    #1,d0
  137.     and.w    #$fff8,d0
  138.     adda.w    d0,a1
  139.     
  140.         ;d5 = count = (x2>>4) - (x1>>4) - 1
  141.     move.w    d3,d5
  142.     asr.w    #4,d5
  143.     move.w    d6,d1
  144.     asr.w    #4,d1
  145.     sub.w    d1,d5
  146.     sub.w    #1,d5
  147.  
  148.         ;mask out where in word endpoints are
  149.     and.w    #$f,d6
  150.     and.w    #$f,d3
  151.         ;word addressing of mask tables
  152.     asl    #1,d6
  153.     asl    #1,d3
  154.  
  155.     ;bra  zblast_block
  156.  
  157.     bra zbblp
  158.  
  159. bblp    
  160.     move.l    a1,a0
  161.     move.w    d6,d2
  162.     move.w    d5,d0
  163.     jsr    (a4)
  164.     adda.w    #160,a1
  165. zbblp    dbra    d7,bblp
  166.  
  167. zblast_block
  168.     movem.l (sp)+,a2/a3/a4/a5/a6/d3/d4/d5/d6/d7
  169.     rts
  170.  
  171.  
  172.  
  173.  
  174.     public _blast_hlines
  175.  
  176. first_param  set 7*4
  177. thread1  set first_param
  178. thread2  set first_param+4
  179. highy     set first_param+8
  180. count     set first_param+10
  181. color     set first_param+12
  182.  
  183. _blast_hlines:
  184.     movem.l    a2/a3/a4/a5/a6/d4,-(sp)
  185.  
  186.         ;set a1 = screen address of first hline
  187.     move.l    _cscreen,a1
  188.     move.w    highy(sp),d0
  189.     mulu    #160,d0
  190.     adda    d0,a1
  191.  
  192.         ;a2 and a3 go to the mask tables
  193.     move.l    #_lmasks,a2
  194.     move.l    #_rmasks,a3
  195.  
  196.         ;a4 points to the hline associated with this color
  197.     move.l    #hline_table,a4    
  198.     move.w    color(sp),d0
  199.     and.w    #15,d0        ;mask color to an ok value
  200.     asl.w    #2,d0            ;pointer addressing ... *4
  201.     move.l    0(a4,d0),a4        ; a4-> color based hline routine
  202.  
  203.     move.l    thread1(sp),a5    ;overwriting static data pointer but it's ok
  204.     move.l    thread2(sp),a6
  205.     move.w    count(sp),d4
  206.     adda    d4,a6    ;    thread2 is backwards so skip to end of it
  207.     adda    d4,a6
  208.     bra    zblast_loop
  209. blast_loop:    move.w    (a5)+,d2
  210.     move.w    -(a6),d3
  211.     cmp.w    d2,d3
  212.     bgt    blast_noswap
  213.     exg    d2,d3
  214.  
  215. blast_noswap:
  216.         ;a1 = line_addr + ((x1>>1)&$fff8)
  217.     move.l    a1,a0
  218.     move.w    d2,d0
  219.     asr.w    #1,d0
  220.     and.w    #$fff8,d0
  221.     adda    d0,a0
  222.     
  223.         ;d0 = count = (x2>>4) - (x1>>4)
  224.     move.w    d3,d0
  225.     asr.w    #4,d0
  226.     move.w    d2,d1
  227.     asr.w    #4,d1
  228.     sub.w    d1,d0
  229.  
  230.         ;mask out where in word endpoints are
  231.     and.w    #$f,d2
  232.     and.w    #$f,d3
  233.         ;word addressing of mask tables
  234.     asl    #1,d2
  235.     asl    #1,d3
  236.  
  237.     subq.w    #1,d0    ;test for within one word (zero count)
  238.     jsr    (a4)    ;and jump to color specific routine
  239.  
  240.     adda    #160,a1
  241. zblast_loop:    dbf    d4,blast_loop    
  242.     movem.l (sp)+,a2/a3/a4/a5/a6/d4
  243.     rts
  244.  
  245.  
  246. hline0:    
  247.         ;if it's all in one word and the masks together and set it!
  248.     bpl    hwords0
  249.     move.w    0(a2,d2.w),d1
  250.     and.w    0(a3,d3.w),d1
  251.     not.w    d1
  252.     and.w    d1,(a0)+
  253.     and.w    d1,(a0)+
  254.     and.w    d1,(a0)+
  255.     and.w    d1,(a0)+
  256.     rts
  257.  
  258. hwords0:
  259.             ;set first word
  260.     move.w    0(a2,d2.w),d1
  261.     not.w    d1
  262.     and.w    d1,(a0)+
  263.     and.w    d1,(a0)+
  264.     and.w    d1,(a0)+
  265.     and.w    d1,(a0)+
  266.     bra    hloopz0
  267.  
  268. hloop0:
  269.     clr.l    (a0)+
  270.     clr.l    (a0)+
  271. hloopz0: dbf    d0,hloop0
  272.  
  273.     move.w    0(a3,d3.w),d1
  274.     not.w    d1
  275.     and.w    d1,(a0)+
  276.     and.w    d1,(a0)+
  277.     and.w    d1,(a0)+
  278.     and.w    d1,(a0)+
  279.     rts
  280.  
  281. hline1: 
  282.         ;if it's all in one word and the masks together and set it!
  283.     bpl    hwords1
  284.     move.w    0(a2,d2.w),d1
  285.     and.w    0(a3,d3.w),d1
  286.     or.w    d1,(a0)+
  287.     not.w    d1
  288.     and.w    d1,(a0)+
  289.     and.w    d1,(a0)+
  290.     and.w    d1,(a0)+
  291.     rts
  292.  
  293. hwords1:
  294.             ;set first word
  295.     move.w    0(a2,d2.w),d1
  296.     or.w    d1,(a0)+
  297.     not.w    d1
  298.     and.w    d1,(a0)+
  299.     and.w    d1,(a0)+
  300.     and.w    d1,(a0)+
  301.  
  302.     move.l    #$ffff0000,d1
  303.     bra    hloopz1
  304. hloop1:
  305.     move.l    d1,(a0)+
  306.     clr.l    (a0)+
  307. hloopz1: dbf    d0,hloop1
  308.  
  309.     move.w    0(a3,d3.w),d1
  310.     or.w    d1,(a0)+
  311.     not.w    d1
  312.     and.w    d1,(a0)+
  313.     and.w    d1,(a0)+
  314.     and.w    d1,(a0)+
  315.     rts
  316.  
  317. hline2: 
  318.         ;if it's all in one word and the masks together and set it!
  319.     bpl    hwords2
  320.     move.w    0(a2,d2.w),d1
  321.     and.w    0(a3,d3.w),d1
  322.     or.w    d1,2(a0)
  323.     not.w    d1
  324.     and.w    d1,(a0)
  325.     and.w    d1,4(a0)
  326.     and.w    d1,6(a0)
  327.     rts
  328.  
  329. hwords2:
  330.             ;set first word
  331.     move.w    0(a2,d2.w),d1
  332.     or.w    d1,2(a0)
  333.     not.w    d1
  334.     and.w    d1,(a0)
  335.     addq    #4,a0
  336.     and.w    d1,(a0)+
  337.     and.w    d1,(a0)+
  338.  
  339.     move.l    #$0000ffff,d1
  340.     bra    hloopz2
  341. hloop2:
  342.     move.l    d1,(a0)+
  343.     clr.l    (a0)+
  344. hloopz2: dbf    d0,hloop2
  345.     move.w    0(a3,d3.w),d1
  346.     or.w    d1,2(a0)
  347.     not.w    d1
  348.     and.w    d1,(a0)
  349.     addq    #4,a0
  350.     and.w    d1,(a0)+
  351.     and.w    d1,(a0)+
  352.     rts
  353.  
  354.  
  355. hline3:
  356.         ;if it's all in one word and the masks together and set it!
  357.     bpl    hwords3
  358.     move.w    0(a2,d2.w),d1
  359.     and.w    0(a3,d3.w),d1
  360.     or.w    d1,(a0)+
  361.     or.w    d1,(a0)+
  362.     not.w    d1
  363.     and.w    d1,(a0)+
  364.     and.w    d1,(a0)+
  365.     rts
  366.  
  367. hwords3:
  368.             ;set first word
  369.     move.w    0(a2,d2.w),d1
  370.     or.w    d1,(a0)+
  371.     or.w    d1,(a0)+
  372.     not.w    d1
  373.     and.w    d1,(a0)+
  374.     and.w    d1,(a0)+
  375.  
  376.     move.l    #$ffffffff,d1
  377.     bra    hloopz3
  378. hloop3:
  379.     move.l    d1,(a0)+
  380.     clr.l    (a0)+
  381. hloopz3: dbf    d0,hloop3
  382.  
  383.     move.w    0(a3,d3.w),d1
  384.     or.w    d1,(a0)+
  385.     or.w    d1,(a0)+
  386.     not.w    d1
  387.     and.w    d1,(a0)+
  388.     and.w    d1,(a0)+
  389.     rts
  390.  
  391.  
  392. hline4:
  393.         ;if it's all in one word and the masks together and set it!
  394.     bpl    hwords4
  395.     move.w    0(a2,d2.w),d1
  396.     and.w    0(a3,d3.w),d1
  397.     or.w    d1,4(a0)
  398.     not.w    d1
  399.     and.w    d1,(a0)+
  400.     and.w    d1,(a0)
  401.     addq    #4,a0
  402.     and.w    d1,(a0)
  403.     rts
  404.  
  405. hwords4:
  406.             ;set first word
  407.     move.w    0(a2,d2.w),d1
  408.     or.w    d1,4(a0)
  409.     not.w    d1
  410.     and.w    d1,(a0)+
  411.     and.w    d1,(a0)+
  412.     addq    #2,a0
  413.     and.w    d1,(a0)+
  414.  
  415.     move.l    #$ffff0000,d1
  416.     bra    hloopz4
  417. hloop4:
  418.     clr.l    (a0)+
  419.     move.l    d1,(a0)+
  420. hloopz4: dbf    d0,hloop4
  421.  
  422.     move.w    0(a3,d3.w),d1
  423.     or.w    d1,4(a0)
  424.     not.w    d1
  425.     and.w    d1,(a0)+
  426.     and.w    d1,(a0)+
  427.     addq    #2,a0
  428.     and.w    d1,(a0)+
  429.     rts
  430.  
  431.  
  432. hline5:
  433.         ;if it's all in one word and the masks together and set it!
  434.     bpl    hwords5
  435.     move.w    0(a2,d2.w),d1
  436.     and.w    0(a3,d3.w),d1
  437.     or.w    d1,(a0)
  438.     or.w    d1,4(a0)
  439.     not.w    d1
  440.     and.w    d1,2(a0)
  441.     and.w    d1,6(a0)
  442.     rts
  443.  
  444. hwords5:
  445.             ;set first word
  446.     move.w    0(a2,d2.w),d1
  447.     or.w    d1,(a0)
  448.     or.w    d1,4(a0)
  449.     not.w    d1
  450.     and.w    d1,2(a0)
  451.     and.w    d1,6(a0)
  452.     addq    #8,a0
  453.  
  454.     move.l    #$ffff0000,d1
  455.     bra    hloopz5
  456. hloop5:
  457.     move.l    d1,(a0)+
  458.     move.l    d1,(a0)+
  459. hloopz5: dbf    d0,hloop5
  460.  
  461.     move.w    0(a3,d3.w),d1
  462.     or.w    d1,(a0)
  463.     or.w    d1,4(a0)
  464.     not.w    d1
  465.     and.w    d1,2(a0)
  466.     and.w    d1,6(a0)
  467.     rts
  468.  
  469.  
  470. hline6:
  471.         ;if it's all in one word and the masks together and set it!
  472.     bpl    hwords6
  473.     move.w    0(a2,d2.w),d1
  474.     and.w    0(a3,d3.w),d1
  475.     or.w    d1,2(a0)
  476.     or.w    d1,4(a0)
  477.     not.w    d1
  478.     and.w    d1,(a0)
  479.     and.w    d1,6(a0)
  480.     rts
  481.  
  482. hwords6:
  483.             ;set first word
  484.     move.w    0(a2,d2.w),d1
  485.     or.w    d1,2(a0)
  486.     or.w    d1,4(a0)
  487.     not.w    d1
  488.     and.w    d1,(a0)
  489.     and.w    d1,6(a0)
  490.     addq    #8,a0
  491.  
  492.     move.l    #$0000ffff,d1
  493.     move.l    #$ffff0000,d2
  494.     bra    hloopz6
  495. hloop6:
  496.     move.l    d1,(a0)+
  497.     move.l    d2,(a0)+
  498. hloopz6: dbf    d0,hloop6
  499.  
  500.     move.w    0(a3,d3.w),d1
  501.     or.w    d1,2(a0)
  502.     or.w    d1,4(a0)
  503.     not.w    d1
  504.     and.w    d1,(a0)
  505.     and.w    d1,6(a0)
  506.     rts
  507.  
  508.  
  509. hline7:
  510.         ;if it's all in one word and the masks together and set it!
  511.     bpl    hwords7
  512.     move.w    0(a2,d2.w),d1
  513.     and.w    0(a3,d3.w),d1
  514.     or.w    d1,(a0)+
  515.     or.w    d1,(a0)+
  516.     or.w    d1,(a0)+
  517.     not.w    d1
  518.     and.w    d1,(a0)+
  519.     rts
  520.  
  521. hwords7:
  522.             ;set first word
  523.     move.w    0(a2,d2.w),d1
  524.     or.w    d1,(a0)+
  525.     or.w    d1,(a0)+
  526.     or.w    d1,(a0)+
  527.     not.w    d1
  528.     and.w    d1,(a0)+
  529.  
  530.     move.l    #$ffffffff,d1
  531.     move.l    #$ffff0000,d2
  532.     bra    hloopz7
  533. hloop7:
  534.     move.l    d1,(a0)+
  535.     move.l    d2,(a0)+
  536. hloopz7: dbf    d0,hloop7
  537.  
  538.     move.w    0(a3,d3.w),d1
  539.     or.w    d1,(a0)+
  540.     or.w    d1,(a0)+
  541.     or.w    d1,(a0)+
  542.     not.w    d1
  543.     and.w    d1,(a0)+
  544.     rts
  545.  
  546.  
  547. hline8:    
  548.         ;if it's all in one word and the masks together and set it!
  549.     bpl    hwords8
  550.     move.w    0(a2,d2.w),d1
  551.     and.w    0(a3,d3.w),d1
  552.     not.w    d1
  553.     and.w    d1,(a0)+
  554.     and.w    d1,(a0)+
  555.     and.w    d1,(a0)+
  556.     not.w    d1
  557.     or.w    d1,(a0)
  558.     rts
  559.  
  560. hwords8:
  561.             ;set first word
  562.     move.w    0(a2,d2.w),d1
  563.     not.w    d1
  564.     and.w    d1,(a0)+
  565.     and.w    d1,(a0)+
  566.     and.w    d1,(a0)+
  567.     not.w    d1
  568.     or.w    d1,(a0)+
  569.  
  570.     move.l    #$0000ffff,d1
  571.     bra    hloopz8
  572. hloop8:
  573.     clr.l    (a0)+
  574.     move.l    d1,(a0)+
  575. hloopz8: dbf    d0,hloop8
  576.  
  577.     move.w    0(a3,d3.w),d1
  578.     not.w    d1
  579.     and.w    d1,(a0)+
  580.     and.w    d1,(a0)+
  581.     and.w    d1,(a0)+
  582.     not.w    d1
  583.     or.w    d1,(a0)
  584.     rts
  585.  
  586. hline9: 
  587.         ;if it's all in one word and the masks together and set it!
  588.     bpl    hwords9
  589.     move.w    0(a2,d2.w),d1
  590.     and.w    0(a3,d3.w),d1
  591.     or.w    d1,(a0)+
  592.     or.w    d1,4(a0)
  593.     not.w    d1
  594.     and.w    d1,(a0)+
  595.     and.w    d1,(a0)
  596.     rts
  597.  
  598. hwords9:
  599.             ;set first word
  600.     move.w    0(a2,d2.w),d1
  601.     or.w    d1,(a0)+
  602.     or.w    d1,4(a0)
  603.     not.w    d1
  604.     and.w    d1,(a0)+
  605.     and.w    d1,(a0)
  606.     addq    #4,a0
  607.  
  608.     move.l    #$ffff0000,d1
  609.     move.l    #$0000ffff,d2
  610.     bra    hloopz9
  611. hloop9:
  612.     move.l    d1,(a0)+
  613.     move.l    d2,(a0)+
  614. hloopz9: dbf    d0,hloop9
  615.  
  616.     move.w    0(a3,d3.w),d1
  617.     or.w    d1,(a0)+
  618.     or.w    d1,4(a0)
  619.     not.w    d1
  620.     and.w    d1,(a0)+
  621.     and.w    d1,(a0)
  622.     rts
  623.  
  624. hlinea: 
  625.         ;if it's all in one word and the masks together and set it!
  626.     bpl    hwordsa
  627.     move.w    0(a2,d2.w),d1
  628.     and.w    0(a3,d3.w),d1
  629.     or.w    d1,2(a0)
  630.     or.w    d1,6(a0)
  631.     not.w    d1
  632.     and.w    d1,(a0)
  633.     and.w    d1,4(a0)
  634.     rts
  635.  
  636. hwordsa:
  637.             ;set first word
  638.     move.w    0(a2,d2.w),d1
  639.     or.w    d1,2(a0)
  640.     or.w    d1,6(a0)
  641.     not.w    d1
  642.     and.w    d1,(a0)
  643.     and.w    d1,4(a0)
  644.     addq    #8,a0
  645.  
  646.     move.l    #$0000ffff,d1
  647.     bra    hloopza
  648. hloopa:
  649.     move.l    d1,(a0)+
  650.     move.l    d1,(a0)+
  651. hloopza: dbf    d0,hloopa
  652.     move.w    0(a3,d3.w),d1
  653.     or.w    d1,2(a0)
  654.     or.w    d1,6(a0)
  655.     not.w    d1
  656.     and.w    d1,(a0)
  657.     and.w    d1,4(a0)
  658.     rts
  659.  
  660.  
  661. hlineb:
  662.         ;if it's all in one word and the masks together and set it!
  663.     bpl    hwordsb
  664.     move.w    0(a2,d2.w),d1
  665.     and.w    0(a3,d3.w),d1
  666.     or.w    d1,(a0)+
  667.     or.w    d1,(a0)+
  668.     or.w    d1,2(a0)
  669.     not.w    d1
  670.     and.w    d1,(a0)
  671.     rts
  672.  
  673. hwordsb:
  674.             ;set first word
  675.     move.w    0(a2,d2.w),d1
  676.     or.w    d1,(a0)+
  677.     or.w    d1,(a0)+
  678.     or.w    d1,2(a0)
  679.     not.w    d1
  680.     and.w    d1,(a0)
  681.     addq    #4,a0
  682.  
  683.     move.l    #$ffffffff,d1
  684.     move.l    #$0000ffff,d2
  685.     bra    hloopzb
  686. hloopb:
  687.     move.l    d1,(a0)+
  688.     move.l    d2,(a0)+
  689. hloopzb: dbf    d0,hloopb
  690.  
  691.     move.w    0(a3,d3.w),d1
  692.     or.w    d1,(a0)+
  693.     or.w    d1,(a0)+
  694.     or.w    d1,2(a0)
  695.     not.w    d1
  696.     and.w    d1,(a0)
  697.     rts
  698.  
  699.  
  700. hlinec:
  701.         ;if it's all in one word and the masks together and set it!
  702.     bpl    hwordsc
  703.     move.w    0(a2,d2.w),d1
  704.     and.w    0(a3,d3.w),d1
  705.     not.w    d1
  706.     and.w    d1,(a0)+
  707.     and.w    d1,(a0)+
  708.     not.w    d1
  709.     or.w    d1,(a0)+
  710.     or.w    d1,(a0)
  711.     rts
  712.  
  713. hwordsc:
  714.             ;set first word
  715.     move.w    0(a2,d2.w),d1
  716.     not.w    d1
  717.     and.w    d1,(a0)+
  718.     and.w    d1,(a0)+
  719.     not.w    d1
  720.     or.w    d1,(a0)+
  721.     or.w    d1,(a0)+
  722.  
  723.     move.l    #$ffffffff,d1
  724.     bra    hloopzc
  725. hloopc:
  726.     clr.l    (a0)+
  727.     move.l    d1,(a0)+
  728. hloopzc: dbf    d0,hloopc
  729.  
  730.     move.w    0(a3,d3.w),d1
  731.     not.w    d1
  732.     and.w    d1,(a0)+
  733.     and.w    d1,(a0)+
  734.     not.w    d1
  735.     or.w    d1,(a0)+
  736.     or.w    d1,(a0)
  737.     rts
  738.  
  739. hlined:
  740.         ;if it's all in one word and the masks together and set it!
  741.     bpl    hwordsd
  742.     move.w    0(a2,d2.w),d1
  743.     and.w    0(a3,d3.w),d1
  744.     or.w    d1,(a0)
  745.     or.w    d1,4(a0)
  746.     or.w    d1,6(a0)
  747.     not.w    d1
  748.     and.w    d1,2(a0)
  749.     rts
  750.  
  751. hwordsd:
  752.             ;set first word
  753.     move.w    0(a2,d2.w),d1
  754.     or.w    d1,(a0)
  755.     or.w    d1,4(a0)
  756.     or.w    d1,6(a0)
  757.     not.w    d1
  758.     and.w    d1,2(a0)
  759.     addq    #8,a0
  760.  
  761.     move.l    #$ffff0000,d1
  762.     move.l    #$ffffffff,d2
  763.     bra    hloopzd
  764. hloopd:
  765.     move.l    d1,(a0)+
  766.     move.l    d2,(a0)+
  767. hloopzd: dbf    d0,hloopd
  768.  
  769.     move.w    0(a3,d3.w),d1
  770.     or.w    d1,(a0)
  771.     or.w    d1,4(a0)
  772.     or.w    d1,6(a0)
  773.     not.w    d1
  774.     and.w    d1,2(a0)
  775.     rts
  776.  
  777.  
  778. hlinee:
  779.         ;if it's all in one word and the masks together and set it!
  780.     bpl    hwordse
  781.     move.w    0(a2,d2.w),d1
  782.     and.w    0(a3,d3.w),d1
  783.     or.w    d1,2(a0)
  784.     or.w    d1,4(a0)
  785.     or.w    d1,6(a0)
  786.     not.w    d1
  787.     and.w    d1,(a0)
  788.     rts
  789.  
  790. hwordse:
  791.             ;set first word
  792.     move.w    0(a2,d2.w),d1
  793.     or.w    d1,2(a0)
  794.     or.w    d1,4(a0)
  795.     or.w    d1,6(a0)
  796.     not.w    d1
  797.     and.w    d1,(a0)
  798.     addq    #8,a0
  799.  
  800.     move.l    #$0000ffff,d1
  801.     move.l    #$ffffffff,d2
  802.     bra    hloopze
  803. hloope:
  804.     move.l    d1,(a0)+
  805.     move.l    d2,(a0)+
  806. hloopze: dbf    d0,hloope
  807.  
  808.     move.w    0(a3,d3.w),d1
  809.     or.w    d1,2(a0)
  810.     or.w    d1,4(a0)
  811.     or.w    d1,6(a0)
  812.     not.w    d1
  813.     and.w    d1,(a0)
  814.     rts
  815.  
  816.  
  817. hlinef:
  818.         ;if it's all in one word and the masks together and set it!
  819.     bpl    hwordsf
  820.     move.w    0(a2,d2.w),d1
  821.     and.w    0(a3,d3.w),d1
  822.     or.w    d1,(a0)+
  823.     or.w    d1,(a0)+
  824.     or.w    d1,(a0)+
  825.     or.w    d1,(a0)
  826.     rts
  827.  
  828. hwordsf:
  829.             ;set first word
  830.     move.w    0(a2,d2.w),d1
  831.     or.w    d1,(a0)+
  832.     or.w    d1,(a0)+
  833.     or.w    d1,(a0)+
  834.     or.w    d1,(a0)+
  835.  
  836.     move.l    #$ffffffff,d1
  837.     bra    hloopzf
  838. hloopf:
  839.     move.l    d1,(a0)+
  840.     move.l    d1,(a0)+
  841. hloopzf: dbf    d0,hloopf
  842.  
  843.     move.w    0(a3,d3.w),d1
  844.     or.w    d1,(a0)+
  845.     or.w    d1,(a0)+
  846.     or.w    d1,(a0)+
  847.     or.w    d1,(a0)
  848.     rts
  849.  
  850.  
  851.  
  852.     dseg
  853.  
  854. hline_table:
  855.     dc.l hline0,hline1,hline2,hline3
  856.     dc.l hline4,hline5,hline6,hline7
  857.     dc.l hline8,hline9,hlinea,hlineb
  858.     dc.l hlinec,hlined,hlinee,hlinef
  859.  
  860.